home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / GROUP3.ASM < prev    next >
Assembly Source File  |  1986-12-13  |  7KB  |  206 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * GROUP 3 (WIndowing) Commands
  14.  
  15.     xref    get_buf,prompt,prtscr,sync_cur,case,cursor
  16.     xref     _getkey,cls,cmd_w,border_w,used,set_w,open_w
  17.     xdef    g_3,refresh
  18.  
  19. #edit.h
  20. #cursor.h
  21.  
  22. *****************************************************************
  23. * G_3 - Group 3 (window) commands processor
  24. g_3:
  25.     move.l    #w_cmd,a0    * load prompt string address
  26.     bsr    prompt        * output prompt
  27.     bsr    _getkey        * get switch key
  28.     and.w    #$001F,d0    * make u/l case into ctrl char
  29.     move.l    #table3,a0    * setup case switch table
  30.     bsr    case        * process choices
  31.     rts            * resume editing
  32. w_cmd:    dc.b    'Window Commands: P R E X',0
  33.     dc.w    0
  34. *****************************************************************
  35. * TABLE3 - switch table for group 3 (window) commands
  36. table3:
  37.     dc.w    4        * four choices
  38.     dc.w    $10        * ^P - pop new window
  39.     dc.l    pop
  40.     dc.w    $12        * ^R - rotate windows
  41.     dc.l    rotate
  42.     dc.w    c_up        * move UL corner of window
  43.     dc.l    upleft
  44.     dc.w    c_down        * move LR corner of window
  45.     dc.l    lowright
  46.     dc.l    default        * "others" choice
  47. default:
  48.     rts
  49. *****************************************************************
  50. * UPLEFT - Moves the upper left corner of the active window
  51. upleft:
  52.     lea    w_ulbx(a5),a2    * pointer to X left side
  53.     lea    w_ulby(a5),a1    * pointer to Y top
  54.     move.w    #lim_lx,d1    * X left limit
  55.     move.w    w_lrbx(a5),d2    * X right limit
  56.     sub.w    #12,d2        * must be at least 10 chars wide
  57.     move.w    #lim_uy,d5    * Y top limit
  58.     move.w    w_lrby(a5),d4    * Y bottom limit
  59.     sub.w    #2,d4        * must be at least 3 high
  60.     bsr    mover        * use common code
  61.     bsr    refresh        * have to remake screen
  62.     rts
  63. *****************************************************************
  64. * LOWRIGHT - moves the lower right corner of the window
  65. lowright:
  66.     lea    w_lrbx(a5),a2    * pointer to X right side
  67.     lea    w_lrby(a5),a1    * pointer to Y bottom
  68.     move.w    #lim_rx,d2    * X right limit
  69.     move.w    w_ulbx(a5),d1    * X left limit
  70.     add.w    #12,d1        * must be at least 10 chars wide
  71.     move.w    #lim_ly,d4    * Y bottom limit
  72.     move.w    w_ulby(a5),d5    * Y top limit
  73.     add.w    #2,d5        * must be at least 3 high
  74.     bsr    mover        * use common code
  75.     bsr    refresh        * have to remake screen
  76.     rts
  77. *****************************************************************
  78. * MOVER - moves the window corners around
  79. mover:
  80.     move.w    (a1),-(a7)    * push cursor Y
  81.     move.w    (a2),-(a7)    * push cursor X
  82.     bsr    cursor        * move cursor to window corner
  83.     addq.l    #4,a7        * adjust stack
  84.     bsr    sync_curs    * make sure cursor moves
  85.     bsr    _getkey        * go see what human has in mind
  86.     move.l    #mtable,a0    * get case switch table ready
  87.     bra    case        * do what human wants... maybe.
  88. *****************************************************************
  89. * MTABLE - window streching case dispatch table
  90. mtable:
  91.     dc.w    9        * 9 choices for this case
  92.     dc.w    c_up        * cursor up
  93.     dc.l    oneup
  94.     dc.w    c_down        * cursor down
  95.     dc.l    onedn
  96.     dc.w    c_right        * cursor right
  97.     dc.l    onert
  98.     dc.w    c_left        * cursor left
  99.     dc.l    onelf
  100.     dc.w    page_up        * max up
  101.     dc.l    allup
  102.     dc.w    page_down    * max down
  103.     dc.l    alldn
  104.     dc.w    c_w_right    * max right
  105.     dc.l    allrt
  106.     dc.w    c_w_left    * max left
  107.     dc.l    alllf
  108.     dc.w    return        * mods complete
  109.     dc.l    done
  110.     dc.l    mover        * default case (no action)
  111. *****************************************************************
  112. oneup:
  113.     cmp.w    (a1),d5        * check top limit
  114.     beq    mover        * branch on limit
  115.     sub.w    #1,(a1)        * move up one line
  116.     bra    mover
  117. *****************************************************************
  118. onedn:
  119.     cmp.w    (a1),d4        * check bottom limit
  120.     beq    mover        * branch on limit
  121.     addq.w    #1,(a1)        * move down one line
  122.     bra    mover
  123. *****************************************************************
  124. onert:
  125.     cmp.w    (a2),d2        * check right limit
  126.     beq    mover        * branch on limit
  127.     addq.w    #1,(a2)        * move one char right
  128.     bra    mover
  129. *****************************************************************
  130. onelf:
  131.     cmp.w    (a2),d1        * check left limit
  132.     beq    mover        * branch on limit
  133.     subq.w    #1,(a2)        * move left one char
  134.     bra    mover
  135. *****************************************************************
  136. allup:
  137.     move.w    d5,(a1)        * set to upper limit
  138.     bra    mover
  139. *****************************************************************
  140. alldn:
  141.     move.w    d4,(a1)        * set to lower limit
  142.     bra    mover
  143. *****************************************************************
  144. alllf:
  145.     move.w    d1,(a2)        * set to left limit
  146.     bra    mover
  147. *****************************************************************
  148. allrt:
  149.     move.w    d2,(a2)        * set to right limit
  150.     bra    mover
  151. *****************************************************************
  152. done:
  153.     move.w    w_ulbx(a5),d0    * reset window params
  154.     move.w    w_ulby(a5),d1    
  155.     move.w    w_lrbx(a5),d2
  156.     move.w    w_lrby(a5),d3
  157.     bsr    set_w        * setup new parameters
  158.     rts
  159. *****************************************************************
  160. * POP - opens a new window for editing
  161. pop:
  162.     bsr    get_buf        * get new buffer
  163.     rts
  164. *****************************************************************
  165. * ROTATE - pulls the bottom active screen to the top.
  166. rotate:
  167.     move.l    a5,a0        * get active screen
  168.     move.l    a5,a1        * prime "last good" pointer
  169. lp0_rt:
  170.     tst.l    (a0)        * is there another window?
  171.     beq    sk0_rt        * no, jump out
  172.     move.l    a0,a1        * save this pointer
  173.     move.l    (a0),a0        * get next window
  174.     bra    lp0_rt        * keep looping
  175. sk0_rt:
  176.     move.l    a5,(a0)        * link to former top window
  177.     move.l    a0,used        * move former bottom to root
  178.     move.l    a0,a5        * make former bottom active
  179.     clr.l    (a1)        * mark last window
  180.     bsr    border_w    * re-establish correct frame
  181.     rts
  182. *****************************************************************
  183. * REFRESH - redraws all screen buffers, leaves a5 set to top win.
  184. refresh:
  185.     bsr    cls        * get rid of stuff on the screen
  186.     clr.w    d1        * count the windows to open
  187.     move.l    #cmd_w,a5    * we have to reopen cmd window
  188.     bsr    open_w        * so we do.
  189.     move.l    used,a5        * get first active window address
  190. lp0_rf:
  191.     move.l    a5,-(a7)    * push a window address
  192.     beq    sk0_rf        * jump out if null
  193.     addq.w    #1,d1        * increment window count
  194.     move.l    (a5),a5        * get next window address
  195.     bra    lp0_rf        * and keep on doon it.
  196. sk0_rf:
  197.     addq.l    #4,a7        * pop null on top of stack
  198.     bra    sk1_rf        * do loop test before loop
  199. lp2_rf:
  200.     move.l    (a7)+,a5    * pop the window
  201.     bsr    open_w        * open the window
  202.     bsr    prtscr        * print the contents
  203. sk1_rf:
  204.     dbra    d1,lp2_rf
  205.     rts
  206.